Quintessential Warrior Macros for Pandaria

(Sticky)

Formerly Quintens Quintessential Warrior Macros
QQ warrior macros was last updated January 4th, 2014

Forward:
To me, a macro is meant to perform an action that would be otherwise too slow, or to cut down on otherwise excessive key bindings. It is not meant to play your character or spam your neighbours. If you want to macro “IN THE BEARD!” to pummel, be my guest but you won’t find that macro here. I prefer to use macros that are controlled and specific. Similarly you won’t find /castsequence macros that do something resembling a dps rotation. I also won’t duplicate a function found in the default ui. If you have a macro that simply reads “/focus”, you can delete it and bind set focus target in the keybindings menu.

I prefer my macros to be precise in what they do, and controlled in execution. If I can use shield wall with what I have equipped currently, I won’t try and equip the shield again. Similarly, if I don’t have a shield equipped, I won’t try to use shield wall. I also have my macros automatically change based on what spec I currently am, and in the past even what stance I was in.

I have appropriated some of these from other players but have written most of them myself. If I have bolded a part of a macro, that means you need to edit it as is logical. Most of these were written or re-written fresh for Pandaria. Since you no longer need /startattack in your macros and stance requirements were removed, it seemed like a good idea. It had been a while since I still had /stopcasting in my weapon swap macros.

On Item Sets:
I use item sets in my macros rather than directly equipped macros. There are four reasons I do this:

    1) Item sets differentiate between items based on their itemstrings, a function unavailable to macros, rather than itemid. In laymen’s terms, it can differentiate between a sword enchanted with landslide and a sword enchanted with mending, or an item with a stam gem vs an item with a mastery gem.
    2) Upon getting an upgrade, or changing your mind, you only need to update the item set, not every macro. This means you can’t forget one and accidentally bring out your old mace with your bladestorm macro.
    3) In WOTLK there was conjecture that it was faster, complete with anecdotal evidence, since it has fewer lines to parse. I have not seen proof of this, nor do I know how such proof could be empirically obtained but I like to think it’s true.
    4) It takes up fewer characters, and this means I can fit more meat and less bread into a macro sandwich.


Setting up item sets
Setting up item sets is easy, open your character frame and then click on the far right icon. Now click the bottom green cross labeled “New Set” and select its name and icon. For the purposes of my macros I use 4 sets labeled “1sword”, “2sword”, “1board”, and “2board”. The sword specs are your offensive sets and your board sets are your defensive sets. Those with the 1 prefix are for your pimary spec, and those with the 2 prefix are for your secondary spec. You can name your weapon swap sets whatever you want, just change the macros appropriately. Change every slot except the weapons to ignore (the red “no” symbol), set the weapons to what you want them to be and hit save.

On modifiers
You can use 3 modifiers in your macros in wow. I use shift and alt because they feel natural to me but you can also use ctrl as a modifier. Just edit the macro appropriately.

Weapon swap macros:

Weapon toggle
#showtooltip [equipped:shields] 17; [noequipped:shields] 16
/equipset [spec:1, equipped:shields] 1sword
/equipset [spec:1, noequipped:shields] 1board
/equipset [spec:2, equipped:shields] 2sword
/equipset [spec:2, noequipped:shields] 2board


What it does:
If you don’t have a shield equipped, it will put on the spec appropriate shield set. If you have a shield equipped it will put on the spec appropriate offensive set.

Fast Wall
#showtooltip Shield Wall
/cancelaura bladestorm
/use Shield Wall
/use [nostance:2]defensive stance


What it does:
It cancels bladestorm, uses shield wall, and puts you into defensive stance.

Mobility Macros:

Intervene
#showtooltip intervene
/cancelaura bladestorm
/use [nomodifier:shift, help][modifier:shift, @targettarget][nomodifier: shift, @playername] Intervene


What it does:
If you are in a bladestorm it will cancel it. If your target is friendly it will intervene them, if you are holding shift it will attempt to intervene what they are targeting, otherwise it will intervene your pre-defined player (you need to add that part in). From this macro you should be able to modify similar macros for other arena partners.

If you have the safeguard talent, you do not need to update the macro since the game will do this automatically.

Mouseover Intervene
#showtooltip Intervene
/use [@mouseover, help] Intervene


What it does:
It will attempt to intervene the target your mouse is hovering over.

Charge
#showtooltip charge
/cancelaura bladestorm
//use [modifier:shift, @focus][nomodifier:shift] charge


What it does:
If you are bladestorming, it will cancel it. If you hold down shift it will charge your focus target, otherwise it will charge your current target.

Always Charge:
#showtooltip pummel
/use pummel
/use charge


What it does:
This macro is an example of a concept. Pummel and charge can safely be macroed together since you are either in range to pummel or out of range and forced to charge. Unless you mash excessively, you won't waste either. The extension of this principle is that you can also bind charge to almost any ability: hamstring, mortal strike, ect... This will, in theory, free up a keybind and provide faster reaction to a moving target. The downsides is you need to relearn how to play to an extent, and you have a risk of erratic behavior.

Intervene Your Mocking Banner
#showtooltip Mocking Banner
/cleartarget [help]
/target mocking banner
/use Intervene
/use mocking banner
/targetlasttarget [help]


What it does:
It will preserve your current target if it is hostile. It will clear it if it is friendly, stopping you from intervening them by accident. It will bring up the targeting circle on the first press, place the banner on a click, then intervene it on the next press.

Just Intervene your Banner
/cleartarget [help]
/target mocking banner
/target demoralizing banner
/use Intervene
/targetlasttarget [help]


What it does:
This just intervenes you to your banner. It won't place it.
Edited by Quinten on 1/3/2014 9:32 PM PST
Reply Quote
Utility macros

Smart Shout
#showtooltip
/use [nomod:alt]Commanding Shout
/stopmacro [nomod:alt]
/run local m,B,C="Shout","Battle Shout ","Commanding Shout" b=select(3, GetMacroInfo(m)) s=strfind(b,B)<40 EditMacro(m,m,nil,gsub(b,s and B or C,s and C or B,1))


What it does:
It will cast commanding shout, if you hit alt when you press it then it will automatically swap to commanding shout (out of combat only). Usefull since it saves a bind given that you are rarely to switch the shout you are using mid fight. All praise be to Ro who first showed me this and Ratatoskr who updated it for the world of rage generation by making it not cast the shout you were moving off of.

Cancel BOP
/cancelaura hand of protection
What it does:
Cancels hand of protection, if it is on you. For keybind conservancy, you can macro it into pummel or spell reflect to ensure these abilities aren't blocked or onto something benign like victory rush. My personal preference is for victory rush as it will not be hit by accident or fire an important cooldown when all you want to do is remove the buff. That macro looks like this:

#showtooltip victory rush
/cancelaura hand of protection
/use victory rush


Vigilance
#showtooltip vigilance
/use [help][@targettarget] vigilance


What it does:
It casts vigilance on your target, but if you are targeting a hostile target, like a raid boss or hostile arena target, it will cast vigilance on what they are targeting.

Stance Taunt
#showtooltip taunt
/cast [nostance: 2] defensive stance
/cast taunt


What it does:
With all abilities being usable in all stances, I have accidentally tanked in battle stance a few times. The first symptom of this is a lack of threat, and this macro slams you into defensive stance when you taunt back if not in the proper stance. You could give shield slam the same treatment, but shifting out of d stance is what I do to drop threat if needed.

Stance Dance Macros

Stance Up
#showtooltip
/use [stance:2] battle stance
/use [stance:1] berserker stance
/use [stance:3] defensive stance

Stance Down

#showtooltip
/use [stance:2] berserker stance
/use [stance:1] Defensive Stance
/use [stance:3] Battle Stance


What they do:
They will cycle you through your stances. Stance Down will move you right across your stance bar while stance up will move you left. You can bind them individually if you want but I like to think of stances as shifting gears on a car and this removes one keybind.

Focus abilities:

What they do:
These macros will use the ability on your focus if you hold down shift. It saves action bar binds and is how I use my focus macros. If you want to bind them separately simply make one that goes /cast [@focus] spellname. You can also use [target=focus] which is the older style.

Pummel
#showtooltip pummel
/use [modifier:shift, @focus][nomodifier:shift] pummel


Heroic Throw 1

#showtooltip Heroic Throw
/use [modifier:shift, @focus][nomodifier:shift] heroic throw

What it does:
It will heroic throw your focus if you are holding down shift, or your target otherwise.

Heroic Throw 2

#showtooltip Heroic Throw
/use [modifier:shift, @focus][nomodifier:shift] heroic throw
/use [nomodifier:shift] throw

What it does:
It will heroic throw your focus if you are holding down shift, or your target otherwise. If you are going after your target, it will also cast throw at the same time for extra damage and saved keybind. The Danger with this keybind is that if you quick swap while tanking it will cause you to cast throw while tanking, thus negating avoidance.

Intimidating Shout

#showtooltip intimidating shout
/use [modifier:shift, @focus][nomodifier:shift] intimidating shout
/stopmacro [modifier:shift]
/stopattack

What it does:
/Stopattack will turn off your auto-attack to prevent you from breaking your intimidating shout. This macro will turn off your auto-attack on your primary target but not if you use it on your focus.

Mouseover macros

Disarm
#showtooltip Disarm
/use [@mouseover, harm][harm]disarm


What it does:
It will attempt to disarm the target your cursor is mousing over. If you are not mousing over a hostile target it will attempt to disarm your current target if it is hostile.

Mouseover Heroic Throw
#showtooltip Heroic Throw
/use [@mouseover, harm][harm]Heroic Throw


What it does:
It will attempt to use heroic throw on the target your cursor is mousing over. If you are not mousing over a hostile target it will attempt to disarm your current target if it is hostile.

Off The GCD Abilities

Guaranteed Raging Blow
#showtooltip Raging Blow
/use [modifier:shift] Berserker Rage
/use raging blow

What it does:
If you hold shift it will hit berserker rage, enraging you to enable the use of raging blow. You can do the same thing for overpower on arms if you want. It won't grant access to special abilities but it will enrage you for extra damage on an ability that can't normally enrage you and is as from from mortal strike in the rotation as possible.

Sweeping Strikes Whirlwind
#showtooltip Whirlwind
/use sweeping strikes
/use whirlwind

What it does:
It casts sweeping strikes and whirlwind and the same time. Of good use in pve, in pvp you may want to use a modifier on sweeping strikes.

Sweeping Strikes Mortal Strike
#showtooltip Mortal Strike
/use [modifier:shift] Sweeping Strikes
/cast Mortal Strike


What it does:
It's another option to keep sweeping strikes up, this time via a modifier on mortal strike. A little more managed.
Edited by Quinten on 4/6/2013 9:35 AM PDT
Reply Quote
Information Macros:
Parry or dodge
/run d=GetDodgeChance() p=GetParryChance() cp=237.186 cd=90.6425 bp=3.21 bd=5.01 x=bp+cp/cd*(d-bd); if (x > p) then DEFAULT_CHAT_FRAME:AddMessage("More parry"); else DEFAULT_CHAT_FRAME:AddMessage("More dodge") end

What it does:
Based on your current level of dodge and parry, and the diminishing returns associated with them, it tells you if you should attain more parry or more dodge. For more accuracy, strip naked and replace bd with your dodge value, and bp with your parry value. This is a must for night elves.

Fix tooltips for talent tiers:
#showtooltip
/use bladestorm
/use shockwave
/use dragon roar
/run local G=GetSpellInfo SetMacroSpell("T5talent", G"Bladestorm" or G"Shockwave" or "Dragon Roar")


What it does:
This is a proof of concept macro for updating tooltips when swapping talents. There are addons that do this, but running this script at the end of the macro will update the talent on keypress. The downside being that you will use the ability when doing this. The name of this macro must be T5talent, but you can edit the macro and name as you see fit.

Basic item use macros:

Top Trinket
#showtooltip 13
/use 13

Bottom Trinket
#showtooltip 14
/use 14

Gloves
#showtooltip10
/use 10

Belt
#showtooltip 6
/use 6

Cloak
#showtooltip 15
/use 15


How they work:
These are the numerical on use commands for using trinkets and engineering tinkers. Use them individually to save time binding upon upgrades or insert them into burst macros as you will.

Example
My lazy pve cooldown sync macro might looks like:
#showtooltip recklessness
/use recklessness
/use bloodbath
/use 10
/use colossus smash

What it does:
It pops your glove tinker, bloodbath, and colossus smash. The cooldowns line up and it is a lazy way to increase if not maximize dps.

A "one shot" macro would look like this:
/use recklessness
/use avatar
/use skull banner
/use 13
/use 10
/use potion of mogu power


What it does:
It pops your glove tinker, your top trinket, recklessness, avatar, and your skull banner and drinks a potion. Line it up and go to town.

Basic arena targeting macros:
/target arena1
/target arena2
/target arena3

You can macro targeting arena opponents by their team position, and this can also be baked into macros using the @ command. For example:

/use [@arena2] intimidating shout


This will cast intimidating shout on the second member of the enemy team.

Focus Swap
/stopmacro [@focus, noexists]
/stopmacro [@target, noexists]
/target focus
/targetlasttarget
/focus
/targetlasttarget


What it does:
If you have both a target and focus set, this macro will swap them. If you are missing either of these components it does nothing.

Taunt Juggle
#showtooltip taunt
/target Frost King Malakk
/use taunt
/targetlasttarget


What it does:
I use this on Council of Elders but the concept transfers. If you need to taunt off on a mob that does not require active tanking/attention this will quickly grab them without much effort.

Concluding remarks
These are all the macros I’m currently using. If you have a clever warrior macro, post it below and I can edit it into the list.
Edited by Quinten on 3/24/2013 9:32 AM PDT
Reply Quote
I have corrected the safeguard provision on the intervene macro and added a new macro for vigilance.
Reply Quote
90 Night Elf Warrior
15370
Nice work

/voted
Reply Quote
Sticky requested:)
Reply Quote
90 Troll Warrior
13895
Sticky also requested, and you've convinced me to change my old equipslot macros to sets as well :)
Reply Quote
90 Human Warrior
7780
Very interesting read Quinten, sticky requested.

Btw, do you have any suggestions/thoughts for an Execute Macro? I'm pretty much a life long Prot warr, so the addition of Execute into my closing rotation is pretty new to me.
Reply Quote
I am not sure what you want to use it for. Execute is 30 rage I have been placing into active defense to secure a kill or using the hard bind for extra dps when I outgear something like a heroic.

You could use a mouseover macro to trigger victory rush when aoe tanking I suppose.

#showtooltip victory rush
/cast [@mouseover] execute


If you can be more specific in what you want it might be doable. You can't realistically automate this ability though. You could however make it stance dependant.
#showtooltip
/cast [stance:2] shield barrier
/cast [stance:1] execute


That would use shield barrier in defensive stance or execute in battle stance.

Oh yeah, I also changed all the macros to use @ rather than target=. I am not sure when they introduced @ but it saves a lot of character space.
Edited by Quinten on 9/8/2012 7:10 PM PDT
Reply Quote
90 Human Warrior
12195
Your deadly calm and heroic strike macro seems to not e very effective. It it much more beneficial to use Deadly calm on cooldown in conjunction with heroic strike /cleave. the macro should look like this and save you a shift modifier.

#showtooltip Heroic Strike
/cast Deadly Calm
/cast Heroic Strike

and the same goes for cleave
Reply Quote
@ Kerex,
I am not so sure about this. There are situations where you want to heroic strike or cleave without hitting deadly calm. Triggering deadly calm automatically can leave you without it when it is most needed.

For instance, if I have a high tfb stack I'll do a normal heroic strike since it is higher damage per rage than slam. If I am rage dumping I will use deadly calm heroic strike. I will consider adding it as an alternative but until theorycrafting proves it is worth using every 1 minute regardless I will leave my macros as is.

The same can be said about cleave as it is often a one time ability use.
Reply Quote
You can find more Warrior macros on this site: http://macro-wow.com/for/warrior/

I like it because its just macros that work and no talking.
Reply Quote
90 Worgen Warrior
7355
Smart Shout
/cast Battle Shout
/script if IsAltKeyDown()then local i,B,C=GetMacroIndexByName("Shout"),"Battle Shout ","Commanding Shout" local b=select(3,GetMacroInfo(i))local s=strfind(b,B)<9 EditMacro(i,"Shout",nil,gsub(b,s and B or C,s and C or B,1)) end


I tinkered around with this a bit, because the way it would use the shout you were trying to switch away from was bugging me. This one will only use the shout when you're not holding the modifier. I use Shift instead of alt, and that's the modifier with the most characters (except for rshift or lshift, but screw that noise). It's right at the character limit as-is, though shortening the macro name or switching to alt or ctrl would alleviate that.
/use [nomod:shift]Battle Shout
/stopmacro [nomod:shift]
/run local i,B,C,b,s=GetMacroIndexByName("Shout"),"Battle Shout ","Commanding Shout" b=select(3,GetMacroInfo(i)) s=strfind(b,B)<20 EditMacro(i,"Shout",nil,gsub(b,s and B or C,s and C or B,1))
Reply Quote
@Ratatoskr. My gnomish cap is off to you sir. I tried to do that when cata launched but failed after going about it in what is now apparently the wrong way. I'm throwing together a minor update to the overall list but will include the alt modified version below. I have my shout on v, and have shift v reserved as prime keybinding real estate for my 90 talent.

/use [nomod:alt]Commanding Shout
/stopmacro [nomod:alt]
/run local i,B,C,b,s=GetMacroIndexByName("Shout"),"Battle Shout ","Commanding Shout" b=select(3,GetMacroInfo(i)) s=strfind(b,B)<20 EditMacro(i,"Shout",nil,gsub(b,s and B or C,s and C or B,1))


edit: The greater post is now updated with this macro, an auto-deadly calm option, and a mouseover disarm macro I have started using now that the stance shift is no longer required.
Edited by Quinten on 9/14/2012 5:14 PM PDT
Reply Quote
85 Worgen Warrior
2315
I have battle shout with charge, that way ill i have to do is focus on charging and if my battle shout is on cooldown i still use the same macro to charge. Helps to have it on at all time in and before combat and if i can't charge but battle shout is ready, same macro. I call it Battle Charge.
Edited by Waykin on 9/14/2012 9:19 PM PDT
Reply Quote
86 Troll Druid
3490
awesome, thanks!
Reply Quote
90 Pandaren Warrior
9365
You are a damn good addition to what I call the warrior All Star team. I will now be searching endlessly for every post you have EVER made, to memorize them like verse.
Reply Quote
Edit: This bug has now been fixed.

As some of you know, you can keep the shield wall buff up without a shield for titans grip fury. So here's the deal. Despite my belief that this a bug, I am going to put in the macro to abuse it.

What all of these do in essence is put on your shield, cast shield wall, and then put your off-hand back on with 2 key presses.

I am torn between including the following macros:

#showtooltip Shield Wall
/cancelaura bladestorm
/cast [worn:shields] Shield Wall
/equipset [spec:1, noworn:shields] 1board
/equipset [spec:2, noworn:shields] 2board
/equipset [spec:1, worn:shields] 1sword
/equipset [spec:2, worn:shields] 2sword


#showtooltip Shield Wall
/cast [worn:shields] Shield Wall
/equipset [spec:1, noworn:shields] 1board
/equipset [spec:2, noworn:shields] 2board
/cast [nostance:2]defensive stance
/equipset [spec:1, worn:shields] 1sword
/equipset [spec:2, worn:shields] 2sword


/cancelaura bladestorm
/cast [worn:shields] Shield Wall
/equipset [spec:1, noworn:shields] 1board
/equipset [spec:2, noworn:shields] 2board
/cast [nostance:2]defensive stance
/equipset [spec:1, worn:shields] 1sword
/equipset [spec:2, worn:shields] 2sword


#showtooltip Shield Wall
/cancelaura bladestorm
/cast [worn:shields] Shield Wall
/equipset [noworn:shields] 1board
/cast [nostance:2]defensive stance
/equipset [worn:shields] 1sword


The issue comes down to character size. By changing my equipped conditionals to worn, which I will likely edit everything to move to, I gathered some extra space but I still need to either cut out:
  • removing bladestorm
  • having it work with weapons that change intelligently via spec
  • showing the tooltip, which lets you see the cooldown
  • or swapping into defensive stance for extra mitigation
  • I am tempted to remove dancing into defensive stance because if you are doing this, you are staying full offense anyways and can manually shift to d-stance if required.

    Is there any input from the community?
    Edited by Quinten on 1/19/2013 9:48 AM PST
    Reply Quote
    90 Worgen Warrior
    7355
    The issue comes down to character size. By changing my equipped conditionals to worn, which I will likely edit everything to move to, I gathered some extra space but I still need to either cut out:
  • removing bladestorm
  • having it work with weapons that change intelligently via spec
  • showing the tooltip, which lets you see the cooldown
  • or swapping into defensive stance for extra mitigation
  • I am tempted to remove dancing into defensive stance because if you are doing this, you are staying full offense anyways and can manually shift to d-stance if required.

    Is there any input from the community?

    Similarly, /use is the same as /cast (they literally call the same command), and "form" in conditionals is the same as "stance." So, trimming out unnecessary spaces and making those 2 changes brings this right to 255 characters (according to macroexplain.com; double-check it, though).
    #showtooltip
    /cancelaura bladestorm
    /use [worn:shields]Shield Wall
    /equipset [spec:1,noworn:shields]1board
    /equipset [spec:2,noworn:shields]2board
    /use [noform:2]defensive stance
    /equipset [spec:1,worn:shields]1sword
    /equipset [spec:2,worn:shields]2sword

    I think the [noform:2] might be redundant, too. I'm pretty sure that in Cataclysm, at least, using a stance you were already in wouldn't do anything; wouldn't activate the stance CD, wouldn't error out, etc. I haven't actually tried it since the patch, though.

    Edit: Oh, just realized that'll mess up the tooltip when you're not wearing a shield. That's harder to get around, unless you don't mind the error about not being able to use it when you don't have a shield equipped. Then you could just /use Shield Wall, and it should be fine.
    Edited by Ratatoskr on 9/17/2012 10:28 AM PDT
    Reply Quote

    Please report any Code of Conduct violations, including:

    Threats of violence. We take these seriously and will alert the proper authorities.

    Posts containing personal information about other players. This includes physical addresses, e-mail addresses, phone numbers, and inappropriate photos and/or videos.

    Harassing or discriminatory language. This will not be tolerated.

    Forums Code of Conduct

    Report Post # written by

    Reason
    Explain (256 characters max)
    Submit Cancel

    Reported!

    [Close]