The Shaman Macro Archive

1 2 3 10 Next
Please be aware that I am no longer actively playing WoW and maintaining this archive. Use these macros as you will. Perhaps someone else will take up this archive.

Question: How do I drop multiple totems at once?
Answer: Get to level 30 and train.

The Shaman Macro Archive
  • [I] - Introduction
  • [II] - Links and credits
  • [III] - Generic Macros
  • [IV] - Enhancement
  • [V] - Elemental
  • [VI] - Restoration

[I] Introduction

This thread is intended to archive macros that are useful to shaman. Some are generic and can be used cross-class, others are spec specific, whilst others are useful for all shaman specs. If you have a macro to share, or have comments or questions, then feel free to post them in this thread. If the macro is useful enough, it may be added to the archive.

To make it easy to navigate this archive, macros are sorted by category. You can quickly search for a category by opening find (typically ctrl + f) on your web browser and search for the index code. Example: searching for '[III]' will take you to the generic macro section.

If you like this shaman macro archive, please click the like button on the side or vote for sticky ^.^

Please note that the majority of these macros work with any modifier key (shift/alt/control) for those that require one. If you wish to specify all/specific modifier key(s), or if you wish the macro to trigger only when there is no modifier key; then use the following:Any modifier key: [mod]
No modifier key: [nomod]
Specified modifier key: [mod:alt] [mod:shift] [mod:ctrl]

[II] Links and Credits

For those interested in learning how to make your own macros, or want something to reference, the following are excellent resources:

If you ever get confused about what a particular macro does, then this site is incredibly useful in explaining it:

Shout out to Cogwheel for his amazing macro guide, which got me started. And thanks to Matuk for his excellent enhancement weapon buffing macro. It was the first weapon buff macro I've come across that actually works properly. ^.^

[III] Generic Macros

Macro Templates

Many of the macros in this thread use or extend on a common macro template. These templates are listed here for reference purposes.

/cast [@focus, nodead][] <spell>
Focus macro template.

/cast [@mouseover, nodead][] <spell>
Mouse-over macro template.

Class Neutral Generic Macros

/focus [@mouseover]This is a quick and easy macro to setting and removing focus targets both before and in combat. Simply bind it to a key and use your mouse to target your new focus target. If the macro is bound to a mouse button then it will NOT work on unit frames.

/use 13
/use 14
The above two macros activates the trinket in the slot specified. 13 is the top trinket slot, 14 is the bottom trinket slot. These macros are useful as they can be used regardless of switching between trinkets. These macros are commonly merged with other spells, particularly with cool-down abilities or consumables in order to maximize their effects.

/script SetCVar("cameraDistanceMax",50)Extends how far you can zoom out the camera. You can use any number instead of 50, but anything over 30 gets the best results.
Shaman Generic Macros

/script for i=1, 4 do DestroyTotem(i) endThis destroys all of your totems without using Totemic Recall. It is also off the global cooldown. This is has a variety of uses, but it mostly highlighted for low level shaman.

/script DestroyTotem(1)This destroys a single totem with the specified slot. Simply change the number to the totem index you desire:
  • 1 - Fire
  • 2 - Earth
  • 3 - Water
  • 4 - Air

There is nothing more generic a shaman macro than a Wind Shear macro and it's variants.

/cast [@focus, harm][] Wind Shear
Casts Wind Shear on your focus target, or your current target if you do not have a focus target.

/cast [mod, @target][@focus, harm][] Wind Shear
Same as the above, however you can temporarily override the focus target setting by holding a modifier key - in order to interrupt your current target.

/cast [@mouseover, harm, nodead][] Wind Shear
A simple mouse-over Wind Shear target. Interrupts your mouse-over target, otherwise interrupts your current target. This can be tricky to use if you have never used mouse-over macros before.

/cast [mod, @focus, harm][]Hex
/stopmacro [@focus, harm, nodead]
/cast [mod, @focus, harm][]Bind Elemental
/stopmacro [@focus, harm, nodead]
Generic CC macros. Casts Hex/Bind Elemental on your current target, or on your focus target if you hold down a modifier key. If you don't have a focus, your current target will become your focus target.

#showtooltip Hex
/clearfocus [mod] [@focus, dead] [@focus, noexists]
/focus [@focus, noexists]
/cast [@focus, harm] Hex
#showtooltip Bind Elemental
/clearfocus [mod] [@focus, dead] [@focus, noexists]
/focus [@focus, noexists]
/cast [@focus, harm] Bind Elemental
Alternative CC macros. Casts Hex/Bind Elemental on your focus if you have one, otherwise it sets your current target as your focus and casts it on them. Hold down a modifier key to clear your focus. Macros are from the Elemental thread, but are cleaned up slightly.

/cast [@mouseover, harm, nodead][] Purge
/cast [@mouseover, help, nodead][] Cleanse Spirit
Generic mouse-over/target macros for purge and cleanse spirit.

/cast [mod, @player] [@mouseover, help, nodead] Cleanse Spirit; [@mouseover, harm, nodead] [harm] Purge; [] Cleanse Spirit
All in one Purge/Cleanse Spirit macro. Works on mouse-over and current targets. Hold a modifier key and it will self cleanse.
#showtooltip ReincarnationThis lets you display the cool down and reagents for Reincarnation on your spell bar (removing the need of an add-on to display this information). Its useful to combine with other macros if you don't need the tooltip displayed.

#showtooltip Bloodlust
/cast [combat][mod] Bloodlust
#showtooltip Heroism
/cast [combat][mod] Heroism
These are safety macros for Bloodlust/Heroism, which prevents them spells from accidentally being used (hotkey or clicked) before a boss pull. With this macro, you can only cast Bloodlust/Heroism during combat. You can override this by holding a modifier key to cast it outside combat.

#showtooltip Ghost Wolf
/cast [noform] Ghost Wolf
This lets you get out of Ghost Wolf form faster than actually re-casting Ghost Wolf again. It has limited uses, but is mostly highlighted during any combat where you need to travel a distance in order to get into a vehicle quickly.

/cast [@mouseover, harm, nodead][] Earth Shock
A generic mouse-over shock macro. Replace Earth Shock by the name of the shock you wish to use (eg: Flame Shock, if you want to be able to multi-dot without loosing your current target.

/cast [harm] Lightning Bolt; [] Healing Wave
/cast [harm] Chain Lightning; [] Chain Heal
One button damage/heal macros designed to reduce the number of spells on your action bars. Casts the offensive spell against hostile targets, otherwise it will cast a healing spell. Can be expanded or paired with different damage and healing spells, although spells with similar cast times or mechanics (eg: Chain Lightning and Chain Heal) tend to be paired together.

#showtooltip [mod] Water Shield; [] Lightning Shield
/cast [noflying, mod] Water Shield; [noflying] Lightning Shield
One button water/lightning shield macro, using a modifier key to switch between them. Also prevents you from dismounting in the air if you have that UI option disabled.
[IV] Enhancement Macros

/cancelform [form]
/petattack [pet]
/cast Stormstrike
The above macro is a fairly generic attack macro for your main melee abilities. Dismount, removing ghost wolf, /startattack and /petattack are all triggered as you hit the macro to use your main melee abilities. Simply replace 'Stormstrike' with 'Lava Lash' if you wish to use a similar macro for Lava Lash.

/cast [mod] Flame Shock
/castsequence [nomod] reset=combat/8 Unleash Elements, Flame Shock
A cast-sequence macro with a catch. This macro combines Unleash Elements and Flame Shock, but only allows you to cast Flame Shock if you have the fire buff from UE active. However, you still have full control over casting Flame Shock via holding down a modifier key. Effectively this macro is indirectly performing a buff check as the Unleash Flame buff lasts for 8 seconds.

/cast [@none, nomod] Windfury Weapon; [@none, mod:shift] Flametongue Weapon; [@none, mod:ctrl] Frostbrand Weapon; [@none, mod:alt] Earthliving Weapon
/use [nomod] 16; 17
/click StaticPopup1Button1
Weapon targeted buffing made easy for enhance. Default: Windfury mainhand, Shift: Flametongue offhand, Ctrl: Frostbrand offhand, Alt: Earthliving offhand. <3 Matuk

/Cast [nopet] Feral Spirit; [] Spirit Walk
/use [nopet] 14
One button macro for Wolves and Spirit walk. Activates your bottom trinket.

/Cast [nopet] Feral Spirit; [mod, @focus][] Bash
One button macro for wolves and bash. Hold modifier key to bash your focus target, otherwise it will bash your current target.

/Cast [nopet] Feral Spirit; [mod, pet] Bash; [] Spirit Walk
/use [nopet] 14
Combination variant of the above two macros as well as activating your bottom trinket. Hold modifier to bash otherwise it will cast spirit walk.

/petattack [mod, @target][@focus][]Causes your pet to attack you focus target if it exists, otherwise it will attack your main target. Hold down a modifier key to ignore your focus target and instead attack your current target.

/run if not oldHasPetUI then oldHasPetUI = HasPetUI; HasPetUI = function() return true, false; end endThis unlocks the pet tab in your character UI in order to see the stats of your wolves. Useful when you combine it with any of the above feral spirit macros.
[V] Elemental Macros

Sadly, I don't have many Elemental macros. Always open to suggestions. :-)

/cast !Earthquake
Removes the toggling of the target circle for Earthquake due to multiple clicks.

/cast Elemental Mastery
/cast Lightning Bolt
/cast Elemental Mastery
/cast Lava Burst
Fairly standard macros for activating Elemental Mastery as well as a primary nuke. You can include /use 13 or /use 14 to activate trinkets along with it.

[VI] Restoration Macros

/cast [@focus, help, nodead][@mouseover, help, nodead][] Earth Shield
/stopmacro [@focus, help, nodead]
/focus [@mouseover, help, nodead][]
This casts Earth Shield onto your helpful focus target. If you don't have a focus target, then it will cast Earth Shield onto your mouse-over or current target, and then set them as your focus target.

/cast !Healing Rain
Removes the toggling of the target circle for Healing Rain due to multiple clicks.

/cast Nature's Swiftness
/cast Greater Healing Wave
/cast Nature's Swiftness
/cast !Healing Rain
Generic emergency instant heal casts. Useful for saving someone at low health or during a brief moment of mobility without having to worry about Spiritwalker's Grace.

/cast [@mouseover, help, nodead][@player] <Healing Spell>
Generic mouse-over healing spell. Replace <healing spell> with whichever spells you wish you cast.

/cast [@mouseovertarget, harm, nodead] Lightning Bolt
Mouse-over assist casting of Lightning Bolt for a Telluric Currents talent build, as your mouse is typically in the proximity of your raid/party frames. This way you don't have to worry about targeting things directly - instead simply mouse-over someone in your party/raid frame. Practically all dps/tanks are targeting something they want killed.

/cast [@focus,harm,nodead][@target,exists] Lightning Bolt
Variant of the above mouse-over assist macro, but instead relies on having a focus or current target set to your kill target.

/cast [@mouseovertarget, harm, nodead] <shock spell>
/cast [@focus,harm,nodead][@target,exists] <shock spell>
Variant of the previous two macros but with a shock spell for a Focused Insight build. Replace <shock spell> with the name of the shock you wish to use.
Stick requested and all five posts voted up, absolutely lovely guide, thank you!

Go go 9th shaman forum sticky : D
Fantastic! Sticky requested and same as Epi.
People complain about the shaman forums... but we ARE the most helpful forum I've ever seen because of stuff like this. ^.^
how do mouse-over macros work?
04/12/2011 06:00 AMPosted by Cestus
how do mouse-over macros work?
Basically, whatever unit is being targeted by your mouse cursor is your mouse-over target. Not only does this include unit frames that your cursor is currently over, but it includes targets in the 3D game world.

In effect, you are pointing at the screen and then hitting a button so that something happens to it.

Various examples from personal experience:
  • Mouse-over frost shocking an alliance trying to run past me on his mount in Alterac Valley. I can hit him with frost shock faster than I can target him and casting it.
  • Moving my mouse over multiple trash mobs and hitting my mouse-over purge macro in order to purge multiple buffs from multiple mobs, whilst dpsing.
  • Interrupting a target that I notice is casting a spell in a multi-mob pull.

Mouse-over macros are not always for everyone. I've played with mouse-overs since they were added to the game just before Burning Crusade came out so I have lots of experience with them. Some people just can't use them due to their play-style.
Requested for sticky.
Great post voting for sticky as we speak
Servers are down atm but ill come back with some ele macros that i use in raid
No offense, but I do not think this is "sticky" material. While a lot of the macros above have their uses, they are not the end-all be-all to every situation and play style in the game. That and there are already several macro writing guides for WoW, particularly in the UI and Macro forums, where players can go and learn how to create macros for themselves.

Basically what I am trying to say is: everyone plays the game differently and these macros are just a bunch play style preference changes, not serious fixes or workarounds to common Shaman problems. For example; you apparently like using offensive mouseover macros, as there a lot of them in your guide here while other players may prefer the exactness of just targeting.

Some of these macros are a little flawed as well, like your Unleash Elements-Flame Shock macro has a castsequence that starts with Unleash Elements and resets every 8 seconds. but Unleash Elements has a 15 second cooldown.
This is why it's an archive. Every person is allowed to post their own macros \ tips \ tricks \ whatever in regards to the class.

Plenty of people run to the shaman forum and ask what useful macros are for their class, so having a compiled list of macros isn't a bad thing.

Either contribute or move along.

(PS: I'll post some macros when I get home.)
I'm well aware of those macro guides, and this isn't aimed to be one. This is simply an archive of useful shaman macros to act as an additional resource.

Weekly, we get people asking about various macros. The most common tends to be about Wind Shear, but there are others. Many macros fall under 3 categories:
  • Focus targeting
  • Mouse-over targeting
  • Combination spell macros targeted towards minimizing buttons used or some alternative goal.

Most of the macros are targeted towards those categories, but there are others that are quite useful - such as the safety bloodlust macro (that one I wrote as a request in WotLK for a trigger happy shaman).

Whilst I intend to add to this archive with user posted macros, not all of them will be added to the main list. I'm not going to add every single Wind Shear, Purge or cooldown related variant, simply because of how similar they actually are to the base variants which people comes across. But, I do want to make sure that the macros that do get added, are quality macros.

If people use these macros then great. If they expand on them then it's even better. It is just here to simply help.

04/12/2011 06:28 AMPosted by Seckszilla
Some of these macros are a little flawed as well, like your Unleash Elements-Flame Shock macro has a castsequence that starts with Unleash Elements and resets every 8 seconds. but Unleash Elements has a 15 second cooldown.
Actually, if you read the description you would see that it was explained. It's hardly what I would call a flawed macro. The macro is using a cast-sequence in order to do an indirect buff check, without actually locking you out of the ability to cast Flame Shock if you so choose.

You can't cast spells based on what buffs you have, but you can use tricks such as the above macro to mimic a buff check.

If you want a flawed macro, then try one of the many enhancement 1 button rotation cast-sequence macros. If there are any other macros in my archive that you think are flawed, then by all means let me know.
Thanks for this. I was actually doing a search yesterday for macros, haven't implemented any yet because I've been short on time.

I've been toying w/ the idea of combining the herbalist skill Lifeblood w/, say, Lightning Bolt or LvB, on a key for increasing haste whenever Lifeblood is available.
Yesterday I found this link which has a lot of ideas. I've not tested any of them yet though:
/cast [harm] Lightning Bolt; [] Healing Wave
That should be a fairly common one Drem.

Join the Conversation

Return to Forum